title Batch movie info downloader
DIALOG CREATE,Batch movie info downloader,-1,0,648,549,-
  DLGTYPE(DRAGDROP),-
  Text(intro1;9;12;313;;Drag and drop movies on the list"," and click on start.),-
  Text(intro2;26;12;342;;Everything after @chr(34).@chr(34) (dot) in a filename will be ignored.),-
  LIST(LIST1;61;12;175;180;SORTED;CLICK),-
  CHECK(go;247;12;163;21;Start the auto search;;CLICK),-
  CHECK(saveImdbAsImage;61;220;194;;Save Imdb Page as image;1;),-
  CHECK(downloadPoster;88;220;107;;Save Poster;1;),-
  CHECK(saveImdbAsHtml;115;220;181;;Save Imdb page as html;1;),-
  CHECK(saveImdbAsmht;115;460;181;;Save Imdb page as mht;1;),-
  CHECK(saveImdbAsHtmZ;142;460;181;;Save Imdb page as htmZ;0;),-
  CHECK(saveImdbAsTxt;142;220;177;;Save Imdb page as text;0;),-
  CHECK(createBookmark;169;220;187;;Save Imdb page address;0;),-
  CHECK(openImdbPageImage;61;460;162;;Open after download;1;;click),- 
  CHECK(openPosterImage;88;460;162;;Open after download;1;;click),-
  CHECK(openurl;169;460;142;;Open when found;0;),-
  Text(addsearchT;199;217;156;;Additional search string),-
  Combo(addsearch;196;460;101;;movie),-
  Text(DelayT;229;217;187;;Delay for page load (in sec.)),-
  Combo(delayC;226;460;101;;5),-
  Text(cutyT;259;217;187;;Capture png program to use),-
  Combo(cutyc;256;460;101;;IECapt.exe),-
  CHECK(dlsubc;286;220;187;;Download Subtitle;0;),-
  Combo(dlsubs;286;460;101;;open_search_program),-
  Text(CheckResultsTitle;302;12;97;;Check results:),-  
  button(BrowseImagesB;322;12;120;;Browse),-
  Text(BrowseImagesT;325;138;195;;Open list in an image browser),- 
  button(OscarB;351;12;120;;Oscar),-
  Text(OscarT;354;138;201;;Open Oscar to search for subtitles),-
  Combo(oscartype;351;460;101;;open_dir),-
  Text(ManualSearchTitle;391;12;107;;Manual Search:),- 
  button(openSearchPageinBrowserB;411;12;120;;Search),-
  Text(ManualSearchText;414;138;233;;Search for the selected item in the list),-
  button(downloadDataManuallyB;440;12;120;;Download),-
  Text(ManualDownloadT;443;138;433;;Copy Imdb address from a web browser"," and click on download),- 
  Text(DebugTitle;477;12;54;;Debug:),-  
  CHECK(ShowHidden;497;15;220;;Show hidden programs running;0;),-
  CHECK(TurboMode;497;280;220;;Turbo Mode;0;CLICK),-
 status(status)



list dlsubs,add,open_search_program
list dlsubs,add,auto_download

list cutyc,add,IECapt.exe
list cutyc,add,CutyCapt.exe
list addsearch,add,movie
list addsearch,add,series
list addsearch,add,

list delayC,add,0
list delayC,add,5
list delayC,add,6

list oscartype,add,open_dir
list oscartype,add,open_file
list oscartype,add,none


INIFILE  OPEN,@path(%0)settings.ini
dialog set,saveImdbAsImage,@INIREAD(setup,saveImdbAsImage,1)
dialog set,downloadPoster,@INIREAD(setup,downloadPoster,1)
dialog set,saveImdbAsHtml,@INIREAD(setup,saveImdbAsHtml,1)
dialog set,saveImdbAsMht,@INIREAD(setup,saveImdbAsMht,1)
dialog set,saveImdbAsHtmZ,@INIREAD(setup,saveImdbAsHtmZ,0)
dialog set,saveImdbAsTxt,@INIREAD(setup,saveImdbAsTxt,0)
dialog set,createBookmark,@INIREAD(setup,createBookmark,0)
dialog set,openImdbPageImage,@INIREAD(setup,openImdbPageImage,0)
dialog set,openPosterImage,@INIREAD(setup,openPosterImage,0)
dialog set,openurl,@INIREAD(setup,openurl,0)
dialog set,addsearch,@INIREAD(setup,addsearch,movie) 
dialog set,delayC,@INIREAD(setup,delayC,5)
dialog set,ShowHidden,@INIREAD(setup,ShowHidden,1)
dialog set,TurboMode,@INIREAD(setup,TurboMode,1)
dialog set,cutyc,@INIREAD(setup,cutyc,IECapt.exe)
dialog set,dlsubc,@INIREAD(setup,dlsubc,0)
dialog set,dlsubs,@INIREAD(setup,dlsubs,open_search_program)
dialog set,oscartype,@INIREAD(setup,oscartype,open_dir)

directory change,@path(%0)
OPTION FIELDSEP,.

rem  CHECK(openTest;220;206;258;;openTest;0;),-


%t = title
%i = info.htm
%s = <a href=@chr(34)/title/tt
%L = 
%f = 
%p =
%q =
%r = 

:evloop
 dialog set,go,0
  wait event
  goto @event()


:CLOSE
INIFILE  OPEN,@path(%0)settings.ini
INIFILE  WRITE,setup,saveImdbAsImage,@dlgtext(saveImdbAsImage)
INIFILE  WRITE,setup,downloadPoster,@dlgtext(downloadPoster)
INIFILE  WRITE,setup,saveImdbAsHtml,@dlgtext(saveImdbAsHtml)
INIFILE  WRITE,setup,saveImdbAsHtmZ,@dlgtext(saveImdbAsHtmZ)
INIFILE  WRITE,setup,saveImdbAsMht,@dlgtext(saveImdbAsMht)
INIFILE  WRITE,setup,saveImdbAsTxt,@dlgtext(saveImdbAsTxt)
INIFILE  WRITE,setup,createBookmark,@dlgtext(createBookmark)
INIFILE  WRITE,setup,openImdbPageImage,@dlgtext(openImdbPageImage)
INIFILE  WRITE,setup,openPosterImage,@dlgtext(openPosterImage)
INIFILE  WRITE,setup,openurl,@dlgtext(openurl)
INIFILE  WRITE,setup,addsearch,@dlgtext(addsearch)
INIFILE  WRITE,setup,delayC,@dlgtext(delayC)
INIFILE  WRITE,setup,ShowHidden,@dlgtext(ShowHidden)
INIFILE  WRITE,setup,TurboMode,@dlgtext(TurboMode)
INIFILE  WRITE,setup,cutyc,@dlgtext(cutyc)
INIFILE  WRITE,setup,dlsubc,@dlgtext(dlsubc)
INIFILE  WRITE,setup,dlsubs,@dlgtext(dlsubs)
INIFILE  WRITE,setup,oscartype,@dlgtext(oscartype)


  exit





:BrowseImagesBbutton
%f = 
%f = listS.txt
if file(@path(%0)%f)
 file delete,@path(%0)%f
 list list1,savefile,@path(%0)%f
 run browser.exe @chr(34)@path(%0)%f@chr(34)
end
  goto evloop


:TurboModeClick
 if @dlgtext(TurboMode)
rem  dialog set,ShowHidden,1
 end
 goto evloop


:OscarBbutton


if @equal(@index(list1),-1)
 list list1,seek,0
end

if @equal(@dlgtext(oscartype),open_dir)
 run oscar\oscar.exe @chr(34)@path(@item(list1))@chr(34)
end

if @equal(@dlgtext(oscartype),open_file)
 run oscar\oscar.exe @chr(34)@item(list1)@chr(34)
end

if @equal(@dlgtext(oscartype),none)
 run oscar\oscar.exe
end

 goto evloop


:RunHiddenOrNotProc

if @dlgtext(ShowHidden)
 run %h,wait 
else
 runh %h,wait 
end

exit



:RunHiddenOrNotProcNOWAIT

if @dlgtext(ShowHidden)
 run %h
else
 runh %h
end

exit






:DRAGDROP
list list1,clear
list list1,dropfiles
  goto evloop


:Parse
 %t =
 parse "%t", @name(@item(list1))

exit

:replaceAmpWith26proc

rem replace "&" with "%26" , so wget does not cut off string
 repeat
  %w = @POS(&,%t)
  %t = @STRDEL(%t,%w,%w)
  %t = @strins(%t,%w,"%26")
 until @zero(@POS(&,%t))
exit



:downloadSearchPage
 rem download search page
 %i = info.htm
 file delete,%i

rem use google
rem  runh cmd /c wget\wget.exe @chr(34)"http://www.imdb.com/search/title?title_type=feature,tv_movie,tv_special,documentary,short,video&title="%t@chr(34) -O %i,wait
wait 1
rem %22 = " 
rem "%22"%t"%22"

%h =
%h = cmd /c wget\wget.exe --user-agent=bmid @chr(34)"http://www.google.com/search?hl=en&num=5&q=imdb "@dlgtext(addsearch) %t@chr(34) -O %i
rem info %h
rem to see query sent to google, unrem line above
gosub RunHiddenOrNotProc

exit


:findMovieAddressPage
rem find Movie Address Page
 %s = http://www.imdb.com/title/tt
 %L = 


if @not(@file(%i))
  %L = noresults
  exit
end

 list 2,create
 list 2,loadfile,%i


 if @zero(@count(2))
  %L = noresults
  list 2,close
  exit
 end


 list 2,seek,0


rem string for google not found: "did not match any documents."
rem not really needed.

 if @not(@MATCH(2,%s))
   %L = noresults
   list 2,close
   exit
 end

  if @MATCH(2,%s)
   %p = 
   %q = 
   %p = @pos(http://www.imdb.com/title/tt,@item(2))
   %L = @substr(@item(2),%p,@len(@item(2)))
   %q = @pos(/@chr(34),%L)


    if @zero(%p)
     %L = noresults
      list 2,close
      exit
    end
    if @zero(%q)
     %L = noresults
      list 2,close
      exit
    end

  %L = @substr(%L,1,%q)
  end
  list 2,close
exit


:downloadPageWithWget
 %i = info.htm
 file delete,%i


%h =
%h = cmd /c wget\wget.exe @chr(34)%L@chr(34) -O %i
gosub RunHiddenOrNotProc


exit


:downloadPageWithWgetInMovieDir
 file delete,index.html
 %i = info.htm
 %r = @item(list1)-web_html.html

rem needs space after k

%h =
%h = cmd /c wget\wget.exe @chr(34)%L@chr(34) -k " " & cmd /c move @chr(34)@path(%0)index.html@chr(34) @chr(34)%r@chr(34)

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end


exit



:downloadPageZWithWgetInMovieDir
 file delete,index.html
 %i = info.htm
 %r = @item(list1)-web_page_zipped

rem needs space after k

%h =
%h = cmd /c del @chr(34)%r.htmz@chr(34) & cmd /c wget\wget.exe  -E -H -k -p -nd --reject=gif","js","swf -Dimdb.com -P @chr(34)%r@chr(34) @chr(34)%L@chr(34) & cmd /c htmz\zip.exe -j -r @chr(34)%r.htmz@chr(34) @chr(34)%r@chr(34) & cmd /c rd /s /q @chr(34)%r@chr(34) 

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end

exit



:downloadPageWithLynx
%I = @path(%0)
%r = @item(list1)-web_txt.wri
DIRECTORY CHANGE,@path(%0)lynx

%h =
%h = cmd /a /c lynx.exe  -dump -nolist -underscore  @chr(34)%L@chr(34) > @chr(34)%r@chr(34)

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end

DIRECTORY CHANGE,%I

exit





:createBookmark
rem create url file
 list 2,create
 list 2,add,[InternetShortcut]
 list 2,add,URL=%L
 list 2,savefile,@item(list1)-web_link.URL
 list 2,close
exit




REM HERE STARTS poster PAGE DOWNLOAD

:searchForPosterUrlInMoviePage
rem get url of poster page
%i = info.htm
%s = primary/images
%B = 

if @file(%i)
 list 2,create
 list 2,loadfile,%i
 
 if @zero(@count(2))
  %B = noresults
  list 2,close
  exit
 end

 list 2,seek,0

  if @MATCH(2,%s)
   %p = @pos(/media/rm,@item(2))
   %s = 
   %s = @substr(@item(2),%p,@len(@item(2)))

   rem s is item2 , starting from %p position, till the end
   %q = @pred(@pos(@chr(34),%s))

    if @zero(%p)
     %B = noresults
      list 2,close
      exit
    end
    if @zero(%q)
     %B = noresults
      list 2,close
      exit
    end
    %B = "http://www.imdb.com"@substr(%s,1,%q)
   else
    %B = noresults
   end

 list 2,close
else
 %B = noresults
end

exit


:downloadHtmlPageWithPosterImage
rem Html Page With Image
 %m = info-poster.htm
 file delete,%m

%h =
%h = cmd /c  wget\wget.exe @chr(34)%B@chr(34) -O %m
gosub RunHiddenOrNotProc

exit


:searchForPosterImageUrlInPosterPage
rem search For PosterImage Url In PosterPage
%m = info-poster.htm
%s = primary-img
if @file(%m)
 list 2,create
 list 2,loadfile,%m

 if @zero(@count(2))
  %B = noresults
  list 2,close
  exit
 end

 list 2,seek,0

  if @MATCH(2,%s)
   %p = @pos(http://,@item(2))
   %q = @pred(@pos(@chr(34) data-,@item(2)))

    if @zero(%p)
     %B = noresults
      list 2,close
      exit
    end
    if @zero(%q)
     %B = noresults
      list 2,close
      exit
    end


   %B = @substr(@item(2),%p,%q)
  else
   %B = noresults
  end
 list 2,close
else
 %B = noresults
end

exit



:downloadPosterImageProc
%r = @item(list1)-poster.jpg

%h =
%h = cmd /c  wget\wget.exe @chr(34)%B@chr(34) -O @chr(34)%r@chr(34)

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end

exit
REM HERE ENDS poster DOWNLOAD PART



:dlsubc

if @equal(@dlgtext(dlsubs),open_search_program)
  if @equal(@index(list1),-1)
   list list1,seek,0
  end
  run oscar\oscar.exe @chr(34)@path(@item(list1))@chr(34)
end

if @equal(@dlgtext(dlsubs),auto_download)
 %I = @path(%0)
 DIRECTORY CHANGE,@path(%0)orca
 %h =
 %h = cmd /c orca d @chr(34)@item(list1)@chr(34)
 gosub RunHiddenOrNotProc
 DIRECTORY CHANGE,%I
end


exit


:openPosterImageProc
%r = @item(list1)-poster.jpg
if @file(%r)
 shell open,%r
end
exit


:openImdbPageImageProc
%r = @item(list1)-web_image.png
if @file(%r)
 shell open,%r
end
exit


:PrintPage

%r = @item(list1)-web_image.png

%h =
%h = cmd /c title Save @chr(34)@name(@item(list1))@chr(34) web page as image"," please wait ... (@dlgtext(cutyc)) & cmd /c CutyCapt\@dlgtext(cutyc) --url=@chr(34)%L@chr(34) --delay=@dlgtext(delayC)000  --out=@chr(34)%r@chr(34)

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end


if @not(@file(%r))
rem wait 1
end

exit


:saveImdbAsMht

 %r = @item(list1)-mht.mht

%h =

%h =  cmd /c title Save @chr(34)@name(@item(list1))@chr(34) web page as .mht"," please wait ... & cmd /c SavePage\SavePage.exe  @chr(34)@name(%r)@chr(34)  @chr(34)%L@chr(34) @chr(34)@path(%r)@chr(34)
rem savepage.exe "yahoo" "http://www.yahoo.com" "c:\
rem info %h

if @dlgtext(TurboMode)
 gosub RunHiddenOrNotProcNOWAIT
else
 gosub RunHiddenOrNotProc
end

exit



:openUrlP
if %L
 run @chr(34)%L@chr(34)
end
exit


:openPosterImageCLICK
if @dlgtext(openPosterImage)
 if @not(@dlgtext(downloadPoster))
  dialog set,downloadPoster,1
 end
end
goto evloop



:openImdbPageImageCLICK
if @dlgtext(openImdbPageImage)
 if @not(@dlgtext(saveImdbAsImage))
  dialog set,saveImdbAsImage,1
 end
end
goto evloop


:goCLICK

if @dlgtext(go)
else
 goto evloop
end

if @zero(@count(list1))
 info Empty list?
 goto evloop
end

dialog set,status, working ...

list list1,seek,0

repeat

 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)]

 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - parse
 gosub parse
 gosub replaceAmpWith26proc
 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadSearchPage
 gosub downloadSearchPage

 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - findMovieAddressPage
 gosub findMovieAddressPage
 if @equal(%L,noresults)
  goto nextline
 end

REM ACTION STARTS HERE, you have the movie address

 if @dlgtext(saveImdbAsImage)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - saveImdbAsImage
  gosub PrintPage
 end


 if @dlgtext(openImdbPageImage)
  gosub openImdbPageImageProc
 end


 if @dlgtext(saveImdbAsMht)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - saveImdbAsMht
  gosub saveImdbAsMht
 end




 if @dlgtext(openUrl)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - openUrl
  gosub openUrlP
 end

 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithWget
 gosub downloadPageWithWget

 if @dlgtext(downloadPoster)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPoster

  gosub searchForPosterUrlInMoviePage
  if @equal(%B,noresults)
   goto skipPoster
  end
  gosub downloadHtmlPageWithPosterImage
  gosub searchForPosterImageUrlInPosterPage
  if @equal(%B,noresults)
   goto skipPoster
  end
  gosub downloadPosterImageProc
 end

:skipPoster

 if %m
  file delete,%m
 end

 if @dlgtext(openPosterImage)
  gosub openPosterImageProc
 end





 if @dlgtext(saveImdbAsTxt)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithLynx
  gosub downloadPageWithLynx
 end

 if @dlgtext(createBookmark)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - createBookmark
  gosub createBookmark
 end

 if @dlgtext(saveImdbAsHtml)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithWgetInMovieDir
  gosub downloadPageWithWgetInMovieDir
 end


 if @dlgtext(saveImdbAsHtmZ)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageZWithWgetInMovieDir
  gosub downloadPageZWithWgetInMovieDir
 end


 if @dlgtext(dlsubc)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPage subtitle
  gosub dlsubc
 end



 if @dlgtext(go)
 else
  dialog set,status,
  goto evloop
 end


:nextline

 if @next(list1)
  if @item(list1)
  end
 end



 if %i
  file delete,%i
 end

 if %m
  file delete,%m
 end


until @Not(@item(list1))
dialog set,status, done.

  goto evloop

:openSearchPageinBrowserBbutton
if @zero(@count(list1))
 info Empty list?
 goto evloop
end

if @equal(@index(list1),-1)
 list list1,seek,0
end

gosub parse
shell open, http://www.imdb.com/find?s=all&q=%t

goto evloop





:downloadDataManuallyBbutton

if @zero(@count(list1))
 info Empty list?
 goto evloop
end

if @equal(@index(list1),-1)
 list list1,seek,0
end

%L = 

list 2,create
list 2,paste
 if @zero(@count(2))
  goto NothingInClipboard
 else
  list 2,seek,0
  %L = @item(2)
 end


:NothingInClipboard
list 2,close

if %L
 if @not(@equal(@substr(%L,1,15),"http://www.imdb"))
   rem check correct address
   %L = http://www.imdb.com/title/ttXXXXXXX
   %L = @INPUT(Enter correct url:,%L)
 end
else
 rem if empty
 %L = http://www.imdb.com/title/ttXXXXXXX
 %L = @INPUT(Enter correct url:,%L)
end

if @ok()
 %i = info.htm
 rem this is for saving items to file dir
 gosub parse
else
 %L = 
 goto evloop
end

REM ACTION STARTS HERE, you have the movie address

 if @dlgtext(saveImdbAsImage)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - saveImdbAsImage
  gosub PrintPage
 end


 if @dlgtext(openImdbPageImage)
  gosub openImdbPageImageProc
 end


 if @dlgtext(saveImdbAsMht)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - saveImdbAsMht
  gosub saveImdbAsMht
 end


 if @dlgtext(openUrl)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - openUrl
  gosub openUrlP
 end

 dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithWget
 gosub downloadPageWithWget

 if @dlgtext(downloadPoster)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPoster

  gosub searchForPosterUrlInMoviePage
  if @equal(%B,noresults)
   goto skipPosterManually
  end
  gosub downloadHtmlPageWithPosterImage
  gosub searchForPosterImageUrlInPosterPage
  if @equal(%B,noresults)
   goto skipPosterManually
  end
  gosub downloadPosterImageProc
 end

:skipPosterManually

 if %m
  file delete,%m
 end

 if @dlgtext(openPosterImage)
  gosub openPosterImageProc
 end




 if @dlgtext(saveImdbAsTxt)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithLynx
  gosub downloadPageWithLynx
 end

 if @dlgtext(createBookmark)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - createBookmark
  gosub createBookmark
 end

 if @dlgtext(saveImdbAsHtml)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPageWithWgetInMovieDir
  gosub downloadPageWithWgetInMovieDir
 end

 if @dlgtext(dlsubc)
  dialog set,status, working ... on @name(@item(list1)).@ext(@item(list1)) [@succ(@index(list1))/@count(list1)] - downloadPage subtitle
  gosub dlsubc
 end


dialog set,status, done.

goto evloop


:LIST1CLICK
%t =
dialog set,status,@item(list1)
  goto evloop













